Ερώτηση για word...

[Stavropoulos Akis]

Μπορώ να τυπώσω μια σελίδα 100 φορές και σε κάθε σελίδα να αλλάζει ο αριθμός σελίδας? Ρωτάω αν υπάρχει κανένας τρόπος γιατί δεν θέλω να κάνω copy-paste μια σελίδα 100 φορές!

[alkisg]

Ναι, απλά κάνεις εισαγωγή -> αριθμοί σελίδων...

Αν δεν το θες στην κεφαλίδα ή στο υποσέλιδο, τότε πας εισαγωγή -> πεδίο -> page.

[Stavropoulos Akis]

Φίλε alkisg όταν κάνω εισαγωγή -> αριθμοί σελίδων ... μου τυπώνει την κάθε σελίδα με τον ίδιο αριθμό σελίδας. Εγώ θέλω τη μία σελίδα που έχω να την τυπώσω 100 φορές και να μου τυπώνει και τον αριθμό σελίδας αυξανόμενο κατά 1. π.χ 1,2,3...100.

[alkisg]

Όχι, με τον αριθμό σελίδας τυπώνει 1, 2, 3, κτλ

Με τον αριθμό σελίδων κάνει αυτό που λες, δηλαδή τυπώνει το πλήθος τους.

 

Στο δεύτερο μενού που σου έδωσα, οι αριθμοί σελίδας λέγονται page ενώ ο αριθμός σελίδων λέγεται numpages.

[chris12]

Βάλε page break στο τελος της σελίδα και κάνε copy 99 φορές ώστε να έχεις 100 σελίδες σύνολο.

 

Κομπογιαννίτικο αλλά σίγουρο.

[alkisg]

Akis σόρρυ, διάβασα βιαστικά την εκφώνηση και κατάλαβα λάθος πράγμα.

 

Αυτό που θες μπορεί να γίνει π.χ. με συγχώνευση αλληλογραφίας. Δηλαδή φτιάχνεις π.χ. ένα Excelόφυλο με τους αριθμούς από 1 ως το 100 (με autocomplete) και μετά στο Word πας Εργαλεία->συγχώνευση αλληλογραφίας, διαλέγεις σαν πηγή το Excelόφυλο και "τραβάς" το μοναδικό πεδίο που έχει (τους αριθμούς) στο σημείο που θες.

[kounoupi]

Θα χρειαστείς 4 πράγματα:

1. Μενού Tools --> Macro --> Security

Επιλογή Medium

ΟΚ

 

2. Μενού Tools --> Options --> Print tab

[v] Update Fields

 

3. Στο σημείο που θες το κείμενο να μετράει θα πατήσεις Ctrl+F9 και θα εμφανίσει { } με γκρι φόντο. Μέσα εκεί θα γράψεις

{ DOCVARIABLE "CopyNum" }

 

4. Θα πας Μενού Tools --> Macro --> Macros

Macro name --> CopyNumbers

Macros in --> τελευταία επιλογή το συγκεκριμένο doc

Create

 

Εκεί που είναι ο κέρσορας θα κοπιάρεις το παρακάτω

 

>    Dim varItem As Variable
   Dim bExists As Boolean
   Dim lCopiesToPrint As Long
   Dim lCounter As Long
   Dim lCopyNumFrom As Long
   
   ' ensure our doc variable exists
   bExists = False
   For Each varItem In ActiveDocument.Variables
       If varItem.Name = "CopyNum" Then
           bExists = True
           Exit For
       End If
   Next varItem
   
   ' initialize document variable if doesn't exist
   If Not bExists Then
       ActiveDocument.Variables.Add _
           Name:="CopyNum", Value:=0
   End If
   
   ' ask how many to print
   lCopiesToPrint = InputBox( _
       Prompt:="How many copies?", _
       Title:="Print And Number Copies", _
       Default:="1")
   
   ' ask where to start numbering
   lCopyNumFrom = CLng(InputBox( _
       Prompt:="Number at which to start numbering copies?", _
       Title:="Print And Number Copies", _
       Default:=CStr(ActiveDocument.Variables("CopyNum") + 1)))
   
   ' loop through the print-write-print cycle
   For lCounter = 0 To lCopiesToPrint - 1
       ' update the document variable
       ActiveDocument.Variables("CopyNum") = _
           lCopyNumFrom + lCounter
       ' print this numbered copy
       ActiveDocument.PrintOut Copies:=1
   Next lCounter

 

Γυρνάς στο doc και τρέχεις την macro που μόλις έφτιαξες

Tools --> Macro --> Macros

Θα σε ρωτήσει πόσες κόπιες θες και από ποιο νούμερο να ξεκινήσει.

Την δεύτερη φορά θα σου προτείνει να ξεκινήσει από το επόμενο νούμερο της πρώτης φοράς

 

Αυτά, πες μου αν το κατάφερες

 

Η λύση σε έτοιμο Doc

http://rapidshare.de/files/16852824/CopyNumbers.doc.html